|
| 1 | +{-# LANGUAGE DataKinds #-} |
| 2 | +{-# LANGUAGE ImportQualifiedPost #-} |
| 3 | +{-# LANGUAGE NumericUnderscores #-} |
| 4 | +{-# LANGUAGE OverloadedStrings #-} |
| 5 | +{-# LANGUAGE RankNTypes #-} |
| 6 | +{-# LANGUAGE RecordWildCards #-} |
| 7 | +{-# LANGUAGE TypeApplications #-} |
| 8 | + |
| 9 | +-- | Implementation of the `hyperlane-message-id` pact native. |
| 10 | +-- |
| 11 | +-- `hyperlane-message-id` takes as input a Pact object representing a |
| 12 | +-- 'HyperlaneMessage', and returns a base16-encoded hash of the abi-encoding |
| 13 | +-- of the input. |
| 14 | +module Crypto.Hash.HyperlaneMessageId (hyperlaneMessageId) where |
| 15 | + |
| 16 | +import Control.Error.Util (hush) |
| 17 | +import Control.Lens ((^?), at, _Just, Prism', _1) |
| 18 | +import Data.ByteString (ByteString) |
| 19 | +import Data.ByteString qualified as BS |
| 20 | +import Data.ByteString.Base16 qualified as Base16 |
| 21 | +import Data.ByteString.Builder (Builder) |
| 22 | +import Data.ByteString.Builder qualified as BB |
| 23 | +import Data.ByteString.Lazy qualified as BL |
| 24 | +import Data.ByteString.Short qualified as BSS |
| 25 | +import Data.Decimal (Decimal) |
| 26 | +import Data.Map (Map) |
| 27 | +import Data.Text (Text) |
| 28 | +import Data.Text qualified as Text |
| 29 | +import Data.Text.Encoding qualified as Text |
| 30 | +import Data.WideWord.Word256 (Word256(..)) |
| 31 | +import Data.Word (Word8, Word32) |
| 32 | +import Ethereum.Misc (keccak256, _getKeccak256Hash, _getBytesN) |
| 33 | +import Pact.Types.Runtime (Object(..), ObjectMap(..), FieldKey, Name, Literal, _TLiteral, _TObject, _LDecimal, _LInteger, _LString) |
| 34 | +import Pact.Types.Term (Term) |
| 35 | + |
| 36 | +---------------------------------------------- |
| 37 | +-- Primitive -- |
| 38 | +---------------------------------------------- |
| 39 | + |
| 40 | +hyperlaneMessageId :: Object Name -> Text |
| 41 | +hyperlaneMessageId o = case decodeHyperlaneMessageObject o of |
| 42 | + Nothing -> error "Couldn't decode HyperlaneMessage" |
| 43 | + Just hm -> getHyperlaneMessageId hm |
| 44 | + |
| 45 | +---------------------------------------------- |
| 46 | +-- Hyperlane Message Encoding -- |
| 47 | +---------------------------------------------- |
| 48 | + |
| 49 | +data HyperlaneMessage = HyperlaneMessage |
| 50 | + { hmVersion :: Word8 -- uint8 |
| 51 | + , hmNonce :: Word32 -- uint32 |
| 52 | + , hmOriginDomain :: Word32 -- uint32 |
| 53 | + , hmSender :: ByteString -- 32x uint8 |
| 54 | + , hmDestinationDomain :: Word32 -- uint32 |
| 55 | + , hmRecipient :: ByteString -- 32x uint8 |
| 56 | + , hmTokenMessage :: TokenMessageERC20 -- variable |
| 57 | + } |
| 58 | + |
| 59 | +packHyperlaneMessage :: HyperlaneMessage -> Builder |
| 60 | +packHyperlaneMessage (HyperlaneMessage{..}) = |
| 61 | + BB.word8 hmVersion |
| 62 | + <> BB.word32BE hmNonce |
| 63 | + <> BB.word32BE hmOriginDomain |
| 64 | + <> BB.byteString (padLeft hmSender) |
| 65 | + <> BB.word32BE hmDestinationDomain |
| 66 | + <> BB.byteString (padLeft hmRecipient) |
| 67 | + <> packTokenMessageERC20 hmTokenMessage |
| 68 | + |
| 69 | +data TokenMessageERC20 = TokenMessageERC20 |
| 70 | + { tmRecipient :: Text -- variable |
| 71 | + , tmAmount :: Word256 -- uint256 |
| 72 | + , tmChainId :: Maybe Word256 -- uint256 |
| 73 | + } |
| 74 | + |
| 75 | +packTokenMessageERC20 :: TokenMessageERC20 -> Builder |
| 76 | +packTokenMessageERC20 t = |
| 77 | + word256BE 64 |
| 78 | + <> word256BE (tmAmount t) |
| 79 | + |
| 80 | + <> word256BE recipientSize |
| 81 | + <> BB.byteString recipient |
| 82 | + where |
| 83 | + (recipient, recipientSize) = padRight (Text.encodeUtf8 (tmRecipient t)) |
| 84 | + |
| 85 | +word256BE :: Word256 -> Builder |
| 86 | +word256BE (Word256 a b c d) = |
| 87 | + BB.word64BE a <> BB.word64BE b <> BB.word64BE c <> BB.word64BE d |
| 88 | + |
| 89 | +-- | Pad with zeroes on the left to 32 bytes |
| 90 | +-- |
| 91 | +-- > padLeft "hello world" |
| 92 | +-- "\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NULhello world" |
| 93 | +padLeft :: ByteString -> ByteString |
| 94 | +padLeft s = BS.replicate (32 - BS.length s) 0 <> s |
| 95 | + |
| 96 | +-- | Pad with zeroes on the right, such that the resulting size is a multiple of 32. |
| 97 | +-- |
| 98 | +-- > padRight "hello world" |
| 99 | +-- ("hello world\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL\NUL",11) |
| 100 | +padRight :: ByteString -> (ByteString, Word256) |
| 101 | +padRight s = |
| 102 | + let |
| 103 | + size = BS.length s |
| 104 | + missingZeroes = restSize size |
| 105 | + in (s <> BS.replicate missingZeroes 0, fromIntegral size) |
| 106 | + |
| 107 | +-- | Returns the modular of 32 bytes. |
| 108 | +restSize :: Integral a => a -> a |
| 109 | +restSize size = (32 - size) `mod` 32 |
| 110 | + |
| 111 | +---------------------------------------------- |
| 112 | +-- Hyperlane Message Hashing -- |
| 113 | +---------------------------------------------- |
| 114 | + |
| 115 | +getHyperlaneMessageId :: HyperlaneMessage -> Text |
| 116 | +getHyperlaneMessageId = |
| 117 | + encodeHex |
| 118 | + . keccak256Hash |
| 119 | + . BL.toStrict |
| 120 | + . BB.toLazyByteString |
| 121 | + . packHyperlaneMessage |
| 122 | + |
| 123 | +keccak256Hash :: ByteString -> ByteString |
| 124 | +keccak256Hash = BSS.fromShort . _getBytesN . _getKeccak256Hash . keccak256 |
| 125 | + |
| 126 | +encodeHex :: ByteString -> Text |
| 127 | +encodeHex b = "0x" <> Text.decodeUtf8 (Base16.encode b) |
| 128 | + |
| 129 | +decodeHex :: Text -> Maybe ByteString |
| 130 | +decodeHex s = do |
| 131 | + h <- Text.stripPrefix "0x" s |
| 132 | + hush (Base16.decode (Text.encodeUtf8 h)) |
| 133 | + |
| 134 | +---------------------------------------------- |
| 135 | +-- Hyperlane Pact Object Decoding -- |
| 136 | +---------------------------------------------- |
| 137 | + |
| 138 | +decodeHyperlaneMessageObject :: Object Name -> Maybe HyperlaneMessage |
| 139 | +decodeHyperlaneMessageObject o = do |
| 140 | + let om = _objectMap (_oObject o) |
| 141 | + |
| 142 | + hmVersion <- fromIntegral @Integer @Word8 <$> grabField om "version" _LInteger |
| 143 | + hmNonce <- fromIntegral @Integer @Word32 <$> grabField om "nonce" _LInteger |
| 144 | + hmOriginDomain <- fromIntegral @Integer @Word32 <$> grabField om "originDomain" _LInteger |
| 145 | + hmSender <- Text.encodeUtf8 <$> grabField om "sender" _LString |
| 146 | + hmDestinationDomain <- fromIntegral @Integer @Word32 <$> grabField om "destinationDomain" _LInteger |
| 147 | + hmRecipient <- decodeHex =<< grabField om "recipient" _LString |
| 148 | + |
| 149 | + let tokenObject = om ^? at "tokenMessage" . _Just . _TObject . _1 |
| 150 | + hmTokenMessage <- case decodeTokenMessageERC20 =<< tokenObject of |
| 151 | + Just t -> pure t |
| 152 | + _ -> error "Couldn't encode TokenMessageERC20" |
| 153 | + |
| 154 | + pure HyperlaneMessage{..} |
| 155 | + |
| 156 | +decodeTokenMessageERC20 :: Object Name -> Maybe TokenMessageERC20 |
| 157 | +decodeTokenMessageERC20 o = do |
| 158 | + let om = _objectMap (_oObject o) |
| 159 | + tmRecipient <- grabField om "recipient" _LString |
| 160 | + tmAmount <- decimalToWord <$> grabField om "amount" _LDecimal |
| 161 | + let tmChainId = Nothing |
| 162 | + pure $ TokenMessageERC20{..} |
| 163 | + |
| 164 | +decimalToWord :: Decimal -> Word256 |
| 165 | +decimalToWord d = |
| 166 | + let ethInWei = 1_000_000_000_000_000_000 -- 1e18 |
| 167 | + in round $ d * ethInWei |
| 168 | + |
| 169 | +grabField :: Map FieldKey (Term Name) -> FieldKey -> Prism' Literal a -> Maybe a |
| 170 | +grabField m key p = m ^? at key . _Just . _TLiteral . _1 . p |
0 commit comments