-
Notifications
You must be signed in to change notification settings - Fork 427
/
Copy pathconfigure.ac
1575 lines (1406 loc) · 66.4 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# configure.ac for the libcoap package
#
# Copyright (C) 2010-2025 Olaf Bergmann <[email protected]>
# Copyright (C) 2015-2018 Carsten Schoenert <[email protected]>
# Copyright (C) 2018-2025 Jon Shallow <[email protected]>
#
# SPDX-License-Identifier: BSD-2-Clause
#
# This file is part of the CoAP library libcoap. Please see README for terms
# of use.
#
# Please run 'autogen.sh' to let autoconf produce a configure script.
# Define the libcoap software version here. Note! The libtool versions are
# defined later.
m4_define([libcoap_major_version], [4])
m4_define([libcoap_minor_version], [3])
m4_define([libcoap_micro_version], [5])
# define an appending release state if needed, for example for pre-releases
# like 'alpha' or 'rc1', for a full release keep the value empty!
# Note: When this is reverted to [] for a full release, then LT_LIBCOAP_CURRENT,
# LT_LIBCOAP_REVISION and LT_LIBCOAP_AGE need updating to update the SO version.
m4_define([libcoap_release_state], [])
# Define the previous full libcoap software release version here.
# Used if libcoap_release_state is not empty for LIBCOAP_VERSION and LIBCOAP_PACKAGE_BASE.
# Set to libcoap software version when libcoap_release_state is reset to empty.
m4_define([libcoap_pre_major_version], [4])
m4_define([libcoap_pre_minor_version], [3])
m4_define([libcoap_pre_micro_version], [4])
# concatenate the full libcoap version string
m4_define([libcoap_version], [m4_format([%s.%s.%s%s], libcoap_major_version, libcoap_minor_version, libcoap_micro_version, libcoap_release_state)])
AC_INIT([libcoap], [libcoap_version], [[email protected]], [libcoap], [https://libcoap.net/])
AC_PREREQ([2.64])
AM_INIT_AUTOMAKE([1.10 -Wall no-define no-dist-gzip dist-bzip2])
PKG_PROG_PKG_CONFIG([0.20])
AM_SILENT_RULES([yes])
AC_HEADER_ASSERT
# Generate one configuration header file for building the library itself with
# an auto generated template. We need later a second one
# (include/coap$LIBCOAP_API_VERSION/libcoap.h) that will be installed alongside the library.
AC_CONFIG_HEADERS([coap_config.h])
AC_PROG_CC
AM_PROG_CC_C_O
AC_PROG_SED
AC_CONFIG_MACRO_DIR([m4])
m4_pattern_allow([AM_PROG_AR])
AM_PROG_AR
AC_PROG_LN_S
AC_PROG_MKDIR_P
AC_C_BIGENDIAN
# enable the automatically build of shared and static libraries
LT_INIT([shared static])
# Setting the libtool versioning
###################################################################################
# #
# To set the version of the library, libtool provides the -version-info #
# parameter, which accepts three numbers, separated by colons, that are called #
# respectively, current, revision and age. Both their name and their behavior, #
# nowadays, have to be considered fully arbitrary, as the explanation provided #
# in the official documentation is confusing to say the least, and can be, in #
# some cases, considered completely wrong. #
# https://autotools.io/libtool/version.html #
# #
###################################################################################
#
# How to work with the libtool versioning?
#
# Follow the following steps from top to bottom. This means always start at point 1
# if you plan to make a release and change the values.
# Every new library starts with a version 'current' (short 'c') = 0
# 'revision' (short 'r') = 0
# 'age' (short 'a') = 0
#
# Update the libtool versioning only just before the release of a public release of libcoap.
# Go through the following checklist from top to bottom and check your needs, following
# the reminded changes if you can say "Yes" for specific check.
#
# 1. Only existing code has changed, no functional changes
# If the library source code has changed but *no* new symbols were added at all
# since the last update, then increment revision (c:r:a becomes c:r+1:a).
# This is usually happen if the existing source of a function was changed for
# bug fixing e.g.
#
# --> Increase the 'LT_LIBCOAP_REVISION' value with *every* new software release
# within one release cycle.
#
# 2. Interfaces were added, functions have changed or are removed
# If any interfaces [exported functions or data] have been added, got internal
# changes that implies a different behavior or removed and by this the visible
# symbols have changed since the last update, increment current, and set
# revision to 0 (c:r:a becomes c+1:r=0:a).
#
# --> Increase the 'LT_LIBCOAP_CURRENT' value whenever as an interface has been added
# or removed. This implies also a API change! You mostly have to change the
# 'libcoap_major_version' or at least 'libcoap_minor_version' then too!
# --> Set 'LT_LIBCOAP_REVISION' to 0.
#
# 3. Interfaces were added but none removed or changed
# If any interfaces have been added since the last public release and non of the
# existing interfaces were removed and existing interfaces have not changed internal
# functionality then the new library is backward compatible. Existing binaries can
# use the new library the same than as the existing old library without loosing
# existing functionality or breakage.
# Increase age by 1 (c:r:a becomes c:r:a+1).
#
# --> Increase the 'LT_LIBCOAP_AGE' value only if the changes made to the ABI are
# backward compatible.
#
# 4. Interfaces were removed or have functional changes
# If any interfaces within the library have been removed since the last public
# release or got some internal changes that let the interface act different than
# before, then set age to 0. The library isn't backwards compatible.
#
# --> Set 'LT_LIBCOAP_AGE' to 0.
# The following explanation may help to understand the above rules a bit better:
# consider that there are three possible kinds of reactions from users of your
# library to changes in a shared library:
#
# 1. Programs using the previous version may use the new version as drop-in
# replacement, and programs using the new version can also work with the
# previous one. In other words, no recompiling nor relinking is needed. In this
# case, bump 'LT_LIBCOAP_REVISION' only, don't touch 'LT_LIBCOAP_CURRENT' nor
# 'LT_LIBCOAP_AGE'.
#
# 2. Programs using the previous version may use the new version
# as drop-in replacement, but programs using the new version may use APIs not
# present in the previous one. In other words, a program linking against the new
# version may fail with 'unresolved symbols' if linking against the old version
# at runtime: set 'LT_LIBCOAP_REVISION' to 0, bump 'LT_LIBCOAP_CURRENT' and
# 'LT_LIBCOAP_AGE'.
#
# 3. Programs may need to be changed, recompiled, and relinked in
# order to use the new version. Bump 'LT_LIBCOAP_CURRENT',
# set 'LT_LIBCOAP_REVISION' and 'LT_LIBCOAP_AGE' to 0.
# To add to the confusion, if LIBCOAP_SO_VERSION is set to 3:0:1 (c:r:a), then the
# .so version naming ends up as 2.1.0 (c-a:a:r) (as decided by libtool).
#
# CAUTION
#
# You will need to manually update various configuration files by running the
# ./configure built script file scripts/fix_version.sh .
#
LT_LIBCOAP_CURRENT=5
LT_LIBCOAP_REVISION=0
LT_LIBCOAP_AGE=2
LIBCOAP_SO_VERSION=$LT_LIBCOAP_CURRENT.$LT_LIBCOAP_REVISION.$LT_LIBCOAP_AGE
# Announce the libtool version
AC_SUBST(LT_LIBCOAP_CURRENT)
AC_SUBST(LT_LIBCOAP_REVISION)
AC_SUBST(LT_LIBCOAP_AGE)
AC_SUBST(LIBCOAP_SO_VERSION)
# Defining the API Version
LIBCOAP_API_VERSION=3
# calculate the ABI version naming as calculated by libtool
m4_pattern_allow(LT_TEMP)
LT_TEMP=$LT_LIBCOAP_CURRENT
LT_TEMP=`expr $LT_TEMP - $LT_LIBCOAP_AGE`
if test "$LT_TEMP" != "$LIBCOAP_API_VERSION" ; then
AC_MSG_ERROR([==> API version ($LIBCOAP_API_VERSION) does not match base of ABI ($LT_TEMP.$LT_LIBCOAP_AGE.$LT_LIBCOAP_REVISION) version.])
fi
LIBCOAP_ABI_VERSION=$LT_TEMP.$LT_LIBCOAP_AGE.$LT_LIBCOAP_REVISION
AC_SUBST(LIBCOAP_ABI_VERSION)
AC_SUBST(LIBCOAP_API_VERSION)
LT_TEMP=libcoap_release_state
if test "x$LT_TEMP" = "x"; then
# Define a numeric version string
m4_define([version_number],
[m4_format([%u%03u%03u],
libcoap_major_version,
libcoap_minor_version,
libcoap_micro_version)])
LIBCOAP_VERSION=version_number
AC_SUBST(LIBCOAP_VERSION)
# Define a base version string
m4_define([base_version],
[m4_format([%u.%u.%u],
libcoap_major_version,
libcoap_minor_version,
libcoap_micro_version)])
LIBCOAP_PACKAGE_BASE=base_version
AC_SUBST(LIBCOAP_PACKAGE_BASE)
else
# Doing a rc1 etc., so not a full release, use previous full version numbers
# Define a numeric version string
m4_define([version_number],
[m4_format([%u%03u%03u],
libcoap_pre_major_version,
libcoap_pre_minor_version,
libcoap_pre_micro_version)])
LIBCOAP_VERSION=version_number
AC_SUBST(LIBCOAP_VERSION)
# Define a base version string
m4_define([base_version],
[m4_format([%u.%u.%u],
libcoap_pre_major_version,
libcoap_pre_minor_version,
libcoap_pre_micro_version)])
LIBCOAP_PACKAGE_BASE=base_version
AC_SUBST(LIBCOAP_PACKAGE_BASE)
fi
# Adding some default warning options for code QS
# see https://gcc.gnu.org/onlinedocs/gcc/Warning-Options.html
# and http://www.gnu.org/software/automake/manual/html_node/Flag-Variables-Ordering.html
WARNING_CFLAGS="\
-pedantic \
-Wall \
-Wcast-qual \
-Wextra \
-Wformat-security \
-Winline \
-Wmissing-declarations \
-Wmissing-prototypes \
-Wnested-externs \
-Wpointer-arith \
-Wshadow \
-Wstrict-prototypes \
-Wswitch-default \
-Wswitch-enum \
-Wunused \
-Wwrite-strings \
"
# check whether or not the compiler supports -Wlogical-op (clang does not...)
AX_CHECK_COMPILE_FLAG([-Wlogical-op], [WARNING_CFLAGS="$WARNING_CFLAGS -Wlogical-op"],,[-Werror])
AX_CHECK_COMPILE_FLAG([-fdiagnostics-color], [CFLAGS="$CFLAGS -fdiagnostics-color"],,[-Werror])
AX_CHECK_COMPILE_FLAG([-Wunused-result], [WARNING_CFLAGS="$WARNING_CFLAGS -Wunused-result"])
# clang 14+ generates dwarf-5, which is not currently supported by valgrind
if test "x$CC" = "xclang"; then
WARNING_CFLAGS="$WARNING_CFLAGS -gdwarf-4"
fi
AC_SUBST([WARNING_CFLAGS])
AX_CHECK_LINK_FLAG([-Wl,--version-script=${srcdir}/libcoap-${LIBCOAP_API_VERSION}.map],
[libcoap_SYMBOLS="-Wl,--version-script=\$(srcdir)/libcoap-\$(LIBCOAP_API_VERSION).map"],
[libcoap_SYMBOLS="-export-symbols \$(top_builddir)/libcoap-\$(LIBCOAP_API_VERSION).sym"])
AC_SUBST(libcoap_SYMBOLS)
# configure options
# __documentation__
AC_ARG_ENABLE([documentation],
[AS_HELP_STRING([--enable-documentation],
[Enable building all the documentation [default=yes]])],
[build_documentation="$enableval"],
[build_documentation="yes"])
AM_CONDITIONAL(BUILD_DOCUMENTATION, [test "x$build_documentation" = "xyes"])
doxygen_version_required=1.7.0
dot_version_required=2.26.0
AC_ARG_ENABLE([doxygen],
[AS_HELP_STRING([--enable-doxygen],
[Enable building the doxygen documentation [default=yes]])],
[build_doxygen="$enableval"],
[build_doxygen="yes"])
if test -z "$enable_doxygen"; then
if test "x$enable_documentation" = "xno"; then
build_doxygen="no"
fi
fi
if test "x$build_doxygen" = "xyes"; then
# Check for doxygen
AC_PATH_PROGS([DOXYGEN], [doxygen])
if test -z "$DOXYGEN"; then
if test "x$build_doxygen" = "xyes"; then
AC_MSG_WARN([==> You want to build the doxygen documentation but doxygen was not found!])
AC_MSG_ERROR([==> Install the package that contains doxygen or disable the doxygen documentation using '--disable-doxygen'.])
fi
else
AC_MSG_CHECKING([for compatible doxygen version (>= $doxygen_version_required)])
doxygen_version=`$DOXYGEN --version`
AS_VERSION_COMPARE([$doxygen_version],
[$doxygen_version_required],
[AC_MSG_RESULT([no])
DOXYGEN=""],
[AC_MSG_RESULT([yes $doxygen_version])],
[AC_MSG_RESULT([yes $doxygen_version])])
if test "x$DOXYGEN" = "x" -a "x$build_doxygen" = "xyes"; then
AC_MSG_WARN([==> Doxygen $doxygen_version too old. Doxygen >= $doxygen_version_required required for documentation build.])
AC_MSG_ERROR([==> Install required doxygen version or disable the doxygen documentation using '--disable-doxygen'.])
else
# we found doxygen and the version is valid
# now checking dot (needed for graphics)
AC_PATH_PROG([DOT], [dot])
if test "x$DOT" = "x"; then
AC_MSG_WARN([==> dot not found - continuing without DOT support])
AC_MSG_WARN([==> The libcoap html documentation will be build without DOT graphics!])
HAVE_DOT="NO"
USE_CALL_GRAPH="NO"
else
AC_MSG_CHECKING([for compatible dot version (>= $dot_version_required)])
case $host in
*-freebsd1*)
# csh and tcsh have a different output redirection than more recent shells
# cmd >& file # Redirect both stdout and stderr to file.
# cmd >>& file # Append both stdout and stderr to file.
# cmd1 | cmd2 # pipe stdout to cmd2
# cmd1 |& cmd2 # pipe stdout and stderr to cmd2
# Using an explicit call with the default always available C-shell on FreeBSD,
# the user may have installed another shell from a port which we don't know here
dot_version=`export DOT=$DOT && csh -c '$DOT -V |& cut -f5 -d" "'`
;;
*)
dot_version=`$DOT -V 2>&1 | cut -f5 -d" "`
;;
esac
AS_VERSION_COMPARE([$dot_version],
[$dot_version_required],
[AC_MSG_RESULT([no])
DOT=""],
[AC_MSG_RESULT([yes $dot_version])],
[AC_MSG_RESULT([yes $dot_version])])
if test "x$DOT" = "x" -a "x$build_doxygen" = "xyes"; then
AC_MSG_WARN([==> Graphviz dot $dot_version too old. Graphviz >= $dot_version_required required for doxygen build.])
AC_MSG_ERROR([==> Install required graphviz version or disable the doxygen documentation using '--disable-doxygen'.])
fi
# we found dot and the version is valid
HAVE_DOT="YES"
# let doxygen create caller graphics
# see http://www.stack.nl/~dimitri/doxygen/manual/config.html#cfg_call_graph
USE_CALL_GRAPH="YES"
# exporting the tests to doc/Doxygen(.in)
AC_SUBST(HAVE_DOT)
AC_SUBST(USE_CALL_GRAPH)
fi
fi
fi
fi
AM_CONDITIONAL(BUILD_DOXYGEN, [test "x$build_doxygen" = "xyes"])
AM_CONDITIONAL([HAVE_DOXYGEN], [test -n "$DOXYGEN"])
AM_COND_IF([HAVE_DOXYGEN], [AC_CONFIG_FILES([doc/Doxyfile])])
# __manpages__
AC_ARG_ENABLE([manpages],
[AS_HELP_STRING([--enable-manpages],
[Enable building the manpages [default=yes]])],
[build_manpages="$enableval"],
[build_manpages="yes"])
if test -z "$enable_manpages"; then
if test "x$enable_documentation" = "xno"; then
build_manpages="no"
fi
fi
if test "x$build_manpages" = "xyes"; then
AC_ARG_VAR([A2X], [a2x command])
AC_PATH_PROG([A2X], [a2x])
if test "x$A2X" = "x"; then
AC_MSG_WARN([==> You want to build the manpages, but a2x was not found!])
AC_MSG_ERROR([==> Install the package that contains a2x (mostly asciidoc) or disable the build of the manpages using '--disable-manpages'.])
build_manpages="no"
else
AX_CHECK_A2X_TO_MANPAGE([], [
AC_MSG_RESULT([no])
AC_MSG_WARN([==> You want to build the manpages with a2x, but manpage formatting does not work!])
AC_MSG_ERROR([==> Install the packages that contains the docbook DTD and XSL stylesheets (presumably docbook, docbook-xml) or disable the build of the manpages using '--disable-manpages'.])
build_manpages="no"
])
fi
fi
AM_CONDITIONAL(BUILD_MANPAGES, [test "x$build_manpages" = "xyes"])
# configure options
# __dtls__
# The Datagram Transport Layer Security (DTLS) feature needs cryptography
# functions.
# We currently support the GnuTLS and OpenSSL library. The user can preselect
# the cryptography library that should be used by adding '--with-gnutls' or
# '--with-openssl'.
# If the user isn't using a selection we first search for GnuTLS and fallback
# to OpenSSL if the GnuTLS library couldn't be found.
gnutls_version_required=3.3.0
openssl_version_required=1.1.0
mbedtls_version_required=2.7.10
wolfssl_version_required=5.2.0
tinydtls_version_required=0.8.6
AC_ARG_ENABLE([dtls],
[AS_HELP_STRING([--enable-dtls],
[Enable building with DTLS support [default=yes]])],
[build_dtls="$enableval"],
[build_dtls="yes"])
AC_ARG_WITH([gnutls],
[AS_HELP_STRING([--with-gnutls],
[Use GnuTLS for DTLS functions])],
[with_gnutls="$withval"],
[with_gnutls="no"])
AC_ARG_WITH([openssl],
[AS_HELP_STRING([--with-openssl],
[Use OpenSSL for DTLS functions])],
[with_openssl="$withval"],
[with_openssl="no"])
AC_ARG_WITH([wolfssl],
[AS_HELP_STRING([--with-wolfssl],
[Use wolfSSL for DTLS functions])],
[with_wolfssl="$withval"],
[with_wolfssl="no"])
AC_ARG_WITH([mbedtls],
[AS_HELP_STRING([--with-mbedtls],
[Use Mbed TLS for DTLS functions])],
[with_mbedtls="$withval"],
[with_mbedtls="no"])
AC_ARG_WITH([tinydtls],
[AS_HELP_STRING([--with-tinydtls],
[Use TinyDTLS for DTLS functions])],
[with_tinydtls="$withval"],
[with_tinydtls="no"])
AC_ARG_WITH([submodule-tinydtls],
[AS_HELP_STRING([--with-submodule-tinydtls],
[Use the TinyDTLS provided in the git submodule over the system-provided version [default=fallback to submodule if --with-tinydtls is explicitly set and no system-provided version was found])])],
[with_submodule_tinydtls="$withval"],
[with_submodule_tinydtls="explicit_fallback"])
if test "x$with_gnutls" = "xyes" -o "x$with_openssl" = "xyes" -o "x$with_wolfssl" = "xyes" -o "x$with_mbedtls" = "xyes" -o "x$with_tinydtls" = "xyes"; then
if test "x$build_dtls" = "xno"; then
# Give an advice that '--with_gnutls', '--with_openssl', '--with_wolfssl', '--with-mbedtls' or '--with-tinydtls' was used but
# DTLS support isn't configured.
AC_MSG_WARN([==> Using the configure options '--with-gnutls', '--with-openssl', '--with_wolfssl', '--with-mbedtls' or '--with-tinydtls' without '--enable-dtls' is useless and will be ignored.])
fi
fi
if test "x$with_submodule_tinydtls" = "xyes"; then
if test "x$with_tinydtls" = "xno"; then
# Give an advice that '--with-submodule-tinydtls' is useless if tinydtls is not also enabled.
AC_MSG_WARN([==> Using the configure option '--with-submodule-tinydtls' without '--with-tinydtls' is useless and it will be ignored.])
fi
fi
# O.K. the user hasn't de-selected DTLS
if test "x$build_dtls" = "xyes"; then
# The user can't select multiple crypto libraries.
TLSCOUNT=0
if test "x$with_gnutls" = "xyes"; then
TLSCOUNT=`expr $TLSCOUNT + 1`
fi
if test "x$with_openssl" = "xyes"; then
TLSCOUNT=`expr $TLSCOUNT + 1`
fi
if test "x$with_wolfssl" = "xyes"; then
TLSCOUNT=`expr $TLSCOUNT + 1`
fi
if test "x$with_mbedtls" = "xyes"; then
TLSCOUNT=`expr $TLSCOUNT + 1`
fi
if test "x$with_tinydtls" = "xyes"; then
TLSCOUNT=`expr $TLSCOUNT + 1`
fi
if test "$TLSCOUNT" -gt 1; then
AC_MSG_ERROR([==> You can't use more than 1 of the options '--with-gnutls', '--with-openssl', '--with-mbedtls' or '--with-tinydtls' at the same time while '--enable-dtls' is selected!
==> Please note, the option '--enable-dtls' is turned on by default if not explicitly disabled!])
fi
# Check for all possible usable and supported SSL crypto libraries
# GnuTLS
PKG_CHECK_MODULES([GnuTLS],
[gnutls],
[have_gnutls="yes"],
[have_gnutls="no"])
# OpenSSL
PKG_CHECK_MODULES([OpenSSL],
[openssl],
[have_openssl="yes"],
[have_openssl="no"])
# wolfSSL
PKG_CHECK_MODULES([wolfSSL],
[wolfssl],
[have_wolfssl="yes"],
[have_wolfssl="no"])
# Mbed TLS
if test "x${MbedTLS_CFLAGS+set}" = "xset"; then
mbedtls_cflags_overridden="yes"
else
mbedtls_cflags_overridden="no"
fi
if test "x${MbedTLS_LIBS+set}" = "xset"; then
mbedtls_libs_overridden="yes"
else
mbedtls_libs_overridden="no"
fi
# If MbedTLS_CFLAGS and MbedTLS_LIBS are overridden, pkg-config will always assume the library was found, even
# though MbedTLS doesn't necessarily have a pkg-config file. Therefore, we might as well use the "old" way to
# determine whether we can link MbedTLS (and which version we have).
if test "x$mbedtls_libs_overridden" = "xyes" -a "x$mbedtls_cflags_overridden" = "xyes"; then
have_mbedtls="no"
mbedtls_has_pkgconfig="no"
else
# Attempt to find MbedTLS using pkg-config.
# When statically linking against libcoap, all transitive dependencies need to be specified as linker flags
# as well. Use pkg-config --static for that.
if test "x$enable_static" = "xyes"; then
KEEP_PKG_CONFIG=$PKG_CONFIG
PKG_CONFIG="$PKG_CONFIG --static"
PKG_CHECK_MODULES([MbedTLS],
[mbedtls],
[have_mbedtls="yes"; mbedtls_has_pkgconfig="yes"],
[have_mbedtls="no"; mbedtls_has_pkgconfig="no"])
PKG_CONFIG=$KEEP_PKG_CONFIG
else
PKG_CHECK_MODULES([MbedTLS],
[mbedtls],
[have_mbedtls="yes"; mbedtls_has_pkgconfig="yes"],
[have_mbedtls="no"; mbedtls_has_pkgconfig="no"])
fi
fi
if test "x$have_mbedtls" = "xno"; then
# Attempt to find mbedtls without pkg-config.
# default linker flags (default CFLAGS are empty, so they don't need to be set).
if test "x$mbedtls_libs_overridden" == "xno"; then
MbedTLS_LIBS="-lmbedtls -lmbedcrypto -lmbedx509"
fi
# check whether we can find MbedTLS
local_MbedTLS_save_CFLAGS=$CFLAGS
CFLAGS="$MbedTLS_CFLAGS $CFLAGS"
local_MbedTLS_save_LIBS=$LIBS
LIBS="$MbedTLS_LIBS $LIBS"
AC_CHECK_LIB(mbedtls, mbedtls_version_get_string,
[have_mbedtls="yes"],
[have_mbedtls="no"])
LIBS=$local_MbedTLS_save_LIBS
CFLAGS=$local_MbedTLS_save_CFLAGS
fi
# here, we know whether we can find MbedTLS, but need to determine the version.
if test "x$have_mbedtls" = "xyes"; then
if test "x$mbedtls_has_pkgconfig" = "xyes"; then
# If pkg-config found mbedtls, use it to determine the version.
mbedtls_version=`$PKG_CONFIG --modversion mbedtls`;
elif test "x$cross_compiling" = "xyes" ; then
# Have no option but to do this
mbedtls_version=$mbedtls_version_required
else
# Get actual library version by compiling a test program.
local_MbedTLS_save_CFLAGS=$CFLAGS
CFLAGS="$MbedTLS_CFLAGS $CFLAGS"
local_MbedTLS_save_LIBS=$LIBS
LIBS="$MbedTLS_LIBS $LIBS"
AC_LANG_PUSH(C)
AC_LINK_IFELSE([dnl
AC_LANG_SOURCE(
[[#include <stdio.h>
#include <mbedtls/version.h>
int main () {
char str[20];
mbedtls_version_get_string(str);
fprintf(stdout,"%s\n",str);
return 0;
}]])],
[mbedtls_version=$(./conftest$EXEEXT)],
[AC_MSG_WARN(Failed to determine Mbed TLS version)
have_mbedtls=no])
AC_LANG_POP(C)
LIBS=$local_MbedTLS_save_LIBS
CFLAGS=$local_MbedTLS_save_CFLAGS
fi
fi
if test "${TinyDTLS_CFLAGS+set}" = "set"; then
tinydtls_cflags_overridden="yes"
fi
if test "${TinyDTLS_LIBS+set}" = "set"; then
tinydtls_libs_overridden="yes"
fi
# TinyDTLS
PKG_CHECK_MODULES([TinyDTLS],
[tinydtls],
[have_tinydtls="yes"],
[have_tinydtls="no"])
# TBD ?
# The user wants to use explicit GnuTLS if '--with-gnutls' was set.
if test "x$with_gnutls" = "xyes"; then
# Some more sanity checking.
if test "x$have_gnutls" != "xyes"; then
AC_MSG_ERROR([==> You want to build libcoap with DTLS support by the GnuTLS library but pkg-config file 'gnutls.pc' could not be found!
Install the package(s) that contains the development files for GnuTLS,
or select a different TLS library or disable the DTLS support using '--disable-dtls'.])
fi
AC_MSG_NOTICE([The use of GnuTLS was explicitly requested with configure option '--with-gnutls'!])
# check for valid GnuTLS version
gnutls_version=`$PKG_CONFIG --modversion gnutls`
AX_CHECK_GNUTLS_VERSION
have_openssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_wolfssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_mbedtls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
fi
# The user wants to use explicit OpenSSL if '--with-openssl was set'.
if test "x$with_openssl" = "xyes"; then
# Some more sanity checking.
if test "x$have_openssl" != "xyes"; then
AC_MSG_ERROR([==> You want to build libcoap with DTLS support by the OpenSSL library but pkg-config file 'openssl.pc' could not be found!
Install the package(s) that contains the development files for OpenSSL,
or select a different TLS library or disable the DTLS support using '--disable-dtls'.])
fi
AC_MSG_NOTICE([The use of OpenSSL was explicitly requested with configure option '--with-openssl'!])
# check for valid OpenSSL version
openssl_version=`$PKG_CONFIG --modversion openssl`
AX_CHECK_OPENSSL_VERSION
have_gnutls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_wolfssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_mbedtls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
fi
# The user wants to use explicit wolfSSL if '--with-wolfssl' was set.
if test "x$with_wolfssl" = "xyes"; then
# Some more sanity checking.
if test "x$have_wolfssl" != "xyes"; then
AC_MSG_ERROR([==> You want to build libcoap with DTLS support by the wolfSSL library but pkg-config file 'wolfssl.pc' could not be found!
Install the package(s) that contains the development files for wolfSSL,
or select a different TLS library or disable the DTLS support using '--disable-dtls'.])
fi
AC_MSG_NOTICE([The use of wolfSSL was explicitly requested with configure option '--with-wolfssl'!])
# check for valid wolfSSL version
wolfssl_version=`$PKG_CONFIG --modversion wolfssl`
AX_CHECK_WOLFSSL_VERSION
have_gnutls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_openssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_mbedtls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
fi
# The user wants to use explicit Mbed TLS if '--with-mbedtls was set'.
if test "x$with_mbedtls" = "xyes"; then
# Some more sanity checking.
if test "x$have_mbedtls" != "xyes"; then
AC_MSG_ERROR([==> You want to build libcoap with DTLS support by the Mbed TLS library but library 'mbedtls' could not be found!
Install the package(s) that contains the development files for Mbed TLS,
or select a different TLS library or disable the DTLS support using '--disable-dtls'.])
fi
AC_MSG_NOTICE([The use of Mbed TLS was explicitly requested with configure option '--with-mbedtls'!])
# mbedtls_version determined previously
AX_CHECK_MBEDTLS_VERSION
have_gnutls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_openssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_wolfssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
fi
# The user wants to use explicit TinyDTLS if '--with-tinydtls was set'.
if test "x$with_tinydtls" = "xyes" ; then
AC_MSG_NOTICE([The use of TinyDTLS was explicitly requested with configure option '--with-tinydtls'!])
if [ test "x$have_tinydtls" = "xno" ] && [ test "x$with_submodule_tinydtls" = "xexplicit_fallback" ] || [ test "x$with_submodule_tinydtls" = "xyes" ]; then
AC_MSG_NOTICE([Using TinyDTLS submodule over system-provided version because either "--with-submodule-tinydtls" was set or no system-provided TinyDTLS was found.])
if test -e "$srcdir/ext/tinydtls/dtls.h"; then
AC_CONFIG_SUBDIRS([ext/tinydtls])
if test "x$enable_shared" = "xyes"; then
auto_TinyDTLS_LIBS="-L\$(top_builddir)/ext/tinydtls -ltinydtls"
else
# Needed as TinyDTLS compiling does not recognize --disable-shared
# and still builds libtinydtls.so which gets linked in otherwise
auto_TinyDTLS_LIBS="-L\$(top_builddir)/ext/tinydtls -l:libtinydtls.a"
fi
have_submodule_tinydtls="yes"
auto_TinyDTLS_CFLAGS="-I \$(top_srcdir)/ext -I \$(top_srcdir)/ext/tinydtls"
if test "x$tinydtls_cflags_overridden" != "xyes"; then
TinyDTLS_CFLAGS="$auto_TinyDTLS_CFLAGS"
fi
if test "x$tinydtls_libs_overridden" != "xyes"; then
TinyDTLS_LIBS="$auto_TinyDTLS_LIBS"
fi
# 'git submodule update' may be required
AC_DEFINE(HAVE_DTLS_SET_LOG_HANDLER, [1], [Define to 1 if TinyDTLS has dtls_set_log_handler.])
else
AC_MSG_ERROR([==> You want to build libcoap with DTLS support using the TinyDTLS submodule library but no suitable version could be found!
Check whether you have updated the TinyDTLS git submodule, use the system-provided version if available (set '--with-submodule-tinydtls=no'),
select a different TLS library or disable the DTLS support using '--disable-dtls'.])
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_submodule_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
fi
elif test "x$have_tinydtls" = "xyes"; then
AC_MSG_NOTICE([Using system-provided TinyDTLS])
tinydtls_version=`$PKG_CONFIG --modversion tinydtls`
AX_CHECK_TINYDTLS_VERSION
AC_CHECK_LIB(tinydtls,dtls_set_log_handler,AC_DEFINE(HAVE_DTLS_SET_LOG_HANDLER, [1], [Define to 1 if TinyDTLS has dtls_set_log_handler.]))
else
AC_MSG_ERROR([==> You want to build libcoap with DTLS support using the TinyDTLS library but no suitable version could be found!
Use the submodule TinyDTLS version (set '--with-submodule-tinydtls=yes' and update the git submodule),
ensure that you have a system-provided version of TinyDTLS that can be found using pkg-config (older versions can not),
select a different TLS library or disable the DTLS support using '--disable-dtls'.])
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
fi
have_gnutls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_openssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_wolfssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_mbedtls="no" # don't confuse AC_MSG_RESULT at the end of the script
fi
if test "$TLSCOUNT" -eq 0; then
# The user hasn't requested the use of a specific cryptography library
# we try first GnuTLS for usability ...
if test "x$have_gnutls" = "xyes"; then
gnutls_version=`$PKG_CONFIG --modversion gnutls`
AX_CHECK_GNUTLS_VERSION
AC_MSG_NOTICE([Using auto selected library GnuTLS for DTLS support!])
with_gnutls_auto="yes"
have_openssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_wolfssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_mbedtls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
# ... and if not found check OpenSSL is suitable.
elif test "x$have_openssl" = "xyes"; then
openssl_version=`$PKG_CONFIG --modversion openssl`
AX_CHECK_OPENSSL_VERSION
AC_MSG_NOTICE([Using auto selected library OpenSSL for DTLS support!])
with_openssl_auto="yes"
have_wolfssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_gnutls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_mbedtls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
# ... and if not found, check if wolfSSL is suitable.
elif test "x$have_wolfssl" = "xyes"; then
wolfssl_version=`$PKG_CONFIG --modversion wolfssl`
AX_CHECK_WOLFSSL_VERSION
AC_MSG_NOTICE([Using auto selected library wolfSSL for DTLS support!])
with_wolfssl_auto="yes"
have_gnutls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_openssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_mbedtls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
# ... and if not found check Mbed TLS is suitable.
elif test "x$have_mbedtls" = "xyes"; then
# Mbed TLS [does not have mbedtls.pc pkg-config file]
# mbedtls_version determined previously
AX_CHECK_MBEDTLS_VERSION
AC_MSG_NOTICE([Using auto selected library Mbed TLS for DTLS support!])
with_mbedtls_auto="yes"
have_gnutls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_wolfssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_openssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_tinydtls="no" # don't confuse AC_MSG_RESULT at the end of the script
elif [ test "x$with_tinydtls" = "xyes" ] && [ test "x$have_tinydtls" = "xyes" ]; then
AC_MSG_NOTICE([Using auto selected library TinyDTLS for DTLS support!])
tinydtls_version=`$PKG_CONFIG --modversion tinydtls`
AX_CHECK_TINYDTLS_VERSION
with_tinydtls_auto="yes"
have_gnutls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_mbedtls="no" # don't confuse AC_MSG_RESULT at the end of the script
have_openssl="no" # don't confuse AC_MSG_RESULT at the end of the script
have_wolfssl="no" # don't confuse AC_MSG_RESULT at the end of the script
# Note that the TinyDTLS submodule is used only when explicitly requested.
# Giving out an error message if we haven't found at least one crypto library.
else
AC_MSG_ERROR([==> Option '--enable-dtls' is set but none of the needed cryptography libraries GnuTLS, OpenSSL, wolfSSL, Mbed TLS or TinyDTLS could be found!
Install at least one of the package(s) that contains the development files for GnuTLS (>= $gnutls_version_required), OpenSSL(>= $openssl_version_required), wolfSSL(>= $wolfssl_version_required), Mbed TLS(>= $mbedtls_version_required), or TinyDTLS(>= $tinydtls_version_required)
or disable the DTLS support using '--disable-dtls'.])
fi
fi
# Saving the DTLS related Compiler flags.
if test "x$with_gnutls" = "xyes" -o "x$with_gnutls_auto" = "xyes"; then
DTLS_CFLAGS="$GnuTLS_CFLAGS"
DTLS_LIBS="$GnuTLS_LIBS"
AC_DEFINE(COAP_WITH_LIBGNUTLS, [1], [Define to 1 if the system has libgnutls28.])
fi
if test "x$with_openssl" = "xyes" -o "x$with_openssl_auto" = "xyes"; then
DTLS_CFLAGS="$OpenSSL_CFLAGS"
DTLS_LIBS="$OpenSSL_LIBS"
AC_DEFINE(COAP_WITH_LIBOPENSSL, [1], [Define to 1 if the system has libssl1.1.])
fi
if test "x$with_wolfssl" = "xyes" -o "x$with_wolfssl_auto" = "xyes"; then
DTLS_CFLAGS="$wolfSSL_CFLAGS"
DTLS_LIBS="$wolfSSL_LIBS"
AC_DEFINE(COAP_WITH_LIBWOLFSSL, [1], [Define to 1 if the system has libwolfssl.])
fi
if test "x$with_mbedtls" = "xyes" -o "x$with_mbedtls_auto" = "xyes"; then
DTLS_CFLAGS="$MbedTLS_CFLAGS"
DTLS_LIBS="$MbedTLS_LIBS"
AC_DEFINE(COAP_WITH_LIBMBEDTLS, [1], [Define to 1 if the system has libmbedtls2.7.10.])
fi
if test "x$with_tinydtls" = "xyes" -o "x$with_tinydtls_auto" = "xyes"; then
DTLS_CFLAGS="$TinyDTLS_CFLAGS"
DTLS_LIBS="$TinyDTLS_LIBS"
AC_DEFINE(COAP_WITH_LIBTINYDTLS, [1], [Define to 1 if the system has libtinydtls.])
fi
AC_SUBST(DTLS_CFLAGS)
AC_SUBST(DTLS_LIBS)
fi
# Define the Library name extension for the TLS the library was linked against
if test "x$with_openssl" = "xyes" -o "x$with_openssl_auto" = "xyes"; then
LIBCOAP_DTLS_LIB_EXTENSION_NAME=-openssl
elif test "x$with_wolfssl" = "xyes" -o "x$with_wolfssl_auto" = "xyes"; then
LIBCOAP_DTLS_LIB_EXTENSION_NAME=-wolfssl
elif test "x$with_gnutls" = "xyes" -o "x$with_gnutls_auto" = "xyes"; then
LIBCOAP_DTLS_LIB_EXTENSION_NAME=-gnutls
elif test "x$with_mbedtls" = "xyes" -o "x$with_mbedtls_auto" = "xyes"; then
LIBCOAP_DTLS_LIB_EXTENSION_NAME=-mbedtls
elif test "x$with_tinydtls" = "xyes"; then
LIBCOAP_DTLS_LIB_EXTENSION_NAME=-tinydtls
else
LIBCOAP_DTLS_LIB_EXTENSION_NAME=-notls
AC_DEFINE(HAVE_NOTLS, [1], [Define to 1 if libcoap has no tls library support.])
fi
AM_CONDITIONAL(HAVE_NOTLS, [test "x$LIBCOAP_DTLS_LIB_EXTENSION_NAME" = "x-notls"])
LIBCOAP_NAME_SUFFIX="$LIBCOAP_API_VERSION$LIBCOAP_DTLS_LIB_EXTENSION_NAME"
AC_SUBST(LIBCOAP_NAME_SUFFIX)
AC_SUBST(LIBCOAP_DTLS_LIB_EXTENSION_NAME)
AC_SUBST([DOLLAR_SIGN],[$])
# configure options
# __OSCORE__
# Support for Object Security according to RFC 8613.
AC_ARG_ENABLE([oscore],
[AS_HELP_STRING([--enable-oscore],
[Enable building with OSCORE support [default=yes]])],
[build_oscore="$enableval"],
[build_oscore="yes"])
if test "x$build_oscore" = "xyes"; then
if test "x$LIBCOAP_DTLS_LIB_EXTENSION_NAME" = "x-notls"; then
AC_MSG_WARN([==> --enable-oscore requires crypto support from TLS library or OS])
fi
fi
if test "x$build_oscore" = "xyes"; then
AC_DEFINE(COAP_OSCORE_SUPPORT, [1], [Define to 1 to build with OSCORE support.])
fi
AM_CONDITIONAL(COAP_OSCORE_SUPPORT, [test "x$build_oscore" = "xyes"])
# configure options
# __tests__
AC_ARG_ENABLE([tests],
[AS_HELP_STRING([--enable-tests],
[Enable building the binary testsuite. Requires --enable-static [default=no]])],
[build_tests="$enableval"],
[build_tests="no"])
if test "x$build_tests" = "xyes"; then
PKG_CHECK_MODULES([CUNIT],
[cunit],
[have_cunit=yes
AC_DEFINE(HAVE_LIBCUNIT, [1], [Define to 1 if the system has libcunit.])],
[have_cunit=no
AC_MSG_WARN([==> You want to build the testing binary but the pkg-config file cunit.pc could not be found or installed CUnit version is too old!])
AC_MSG_ERROR([==> Install the package(s) that contains the development files for CUnit or disable the testing binary using '--disable-tests'.])
])
if test "x$enable_static" = "xno"; then
enable_static=yes
AC_MSG_WARN([--enable-tests requires --enable-static which is now enabled.])
fi
fi
AM_CONDITIONAL(HAVE_CUNIT, [test "x$CUNIT_LIBS" != "x"])
# configure options
# __examples__
AC_ARG_ENABLE([examples],
[AS_HELP_STRING([--enable-examples],
[Enable building the example binaries [default=yes]])],
[build_examples="$enableval"],
[build_examples="yes"])
AM_CONDITIONAL(BUILD_EXAMPLES, [test "x$build_examples" = "xyes"])
# configure options
# __examples-source
AC_ARG_ENABLE([examples-source],
[AS_HELP_STRING([--enable-examples-source],
[Enable installing example source to DATAROOTDIR/libcoap/examples [default=yes]])],
[build_examples_source="$enableval"],
[build_examples_source="yes"])
AM_CONDITIONAL(BUILD_EXAMPLES_SOURCE, [test "x$build_examples_source" = "xyes"])
# configure options
# __gcov__
AC_ARG_ENABLE([gcov],
[AS_HELP_STRING([--enable-gcov],
[Enable building with gcov test coverage support [default=no]])],
[build_gcov="$enableval"],
[build_gcov="no"
AC_MSG_WARN([gcov is disabled])
])
if test "x$build_gcov" = "xyes"; then
if test "x$GCC" != "xyes"; then
AC_MSG_ERROR([Currently, gcov is assumed to work with GCC-compatible compilers only.])
else
AX_CHECK_COMPILE_FLAG([-fprofile-arcs], [CFLAGS="$CFLAGS -fprofile-arcs"])
AX_CHECK_COMPILE_FLAG([-ftest-coverage], [CFLAGS="$CFLAGS -ftest-coverage"])
# FIXME: clang complains about '--coverage'
AX_CHECK_COMPILE_FLAG([--coverage], [CFLAGS="$CFLAGS --coverage -O0" LDFLAGS="$LDFLAGS --coverage"])
fi
fi
# configure options
# __license-install__
AC_ARG_ENABLE([license-install],
[AS_HELP_STRING([--enable-license-install],
[Enable installing LICENSE to DOCDIR [default=yes]])],
[build_license_install="$enableval"],
[build_license_install="yes"])
AM_CONDITIONAL(BUILD_LICENSE_INSTALL, [test "x$build_license_install" = "xyes"])
# configure options
# __ipv4__
AC_ARG_ENABLE([ipv4],
[AS_HELP_STRING([--enable-ipv4-support],
[Enable building with support for IPv4 packets [default=yes]])],
[build_ipv4_support="$enableval"],
[build_ipv4_support="yes"])
AS_IF([test "x$build_ipv4_support" = "xyes"],
[AC_DEFINE(COAP_IPV4_SUPPORT, [1], [Define to build support for IPv4 packets.])])
# configure options
# __ipv6__
AC_ARG_ENABLE([ipv6],
[AS_HELP_STRING([--enable-ipv6-support],
[Enable building with support for IPv6 packets [default=yes]])],
[build_ipv6_support="$enableval"],
[build_ipv6_support="yes"])
AS_IF([test "x$build_ipv6_support" = "xyes"],
[AC_DEFINE(COAP_IPV6_SUPPORT, [1], [Define to build support for IPv6 packets.])])
# configure options
# __af_unix__
AC_ARG_ENABLE([af_unix],
[AS_HELP_STRING([--enable-af-unix-support],
[Enable building with support for Unix socket packets [default=yes]])],
[build_af_unix_support="$enableval"],
[build_af_unix_support="yes"])
AS_IF([test "x$build_af_unix_support" = "xyes"],
[AC_DEFINE(COAP_AF_UNIX_SUPPORT, [1], [Define to build support for Unix socket packets.])])
# configure options
# __tcp__
AC_ARG_ENABLE([tcp],
[AS_HELP_STRING([--enable-tcp],
[Enable building with TCP support [default=yes]])],
[build_tcp="$enableval"],
[build_tcp="yes"])
AC_DEFINE(COAP_DISABLE_TCP, [0], [Define to 1 to build without TCP support.])
AS_IF([test "x$build_tcp" != "xyes"], [AC_DEFINE(COAP_DISABLE_TCP, [1])])