Expose local browser drivers through bazel

Author: shs96c

WORKSPACE

@@ -239,3 +239,7 @@ k8s_defaults(
     kind = "deployment",
     namespace = "selenium",
 )
+
+load("//common:repositories.bzl", "pin_browsers")
+
+pin_browsers()

common/BUILD.bazel

@@ -1,23 +1,58 @@
+package(default_visibility = ["//visibility:public"])
+
 config_setting(
     name = "linux",
     constraint_values = ["@platforms//os:linux"],
-    visibility = ["//visibility:public"],
 )
 
 config_setting(
     name = "macos",
     constraint_values = ["@platforms//os:macos"],
-    visibility = ["//visibility:public"],
 )
 
 config_setting(
     name = "windows",
     constraint_values = ["@platforms//os:windows"],
-    visibility = ["//visibility:public"],
 )
 
 # Are we creating a stamped build?
 config_setting(
     name = "stamp",
     values = {"stamp": "true"},
 )
+
+alias(
+    name = "chromedriver",
+    actual = "@local_drivers//:chromedriver",
+)
+
+config_setting(
+    name = "use_local_chromedriver",
+    flag_values = {
+        "@local_drivers//:use_chromedriver": "true",
+    },
+)
+
+alias(
+    name = "geckodriver",
+    actual = "@local_drivers//:geckodriver",
+)
+
+config_setting(
+    name = "use_local_geckodriver",
+    flag_values = {
+        "@local_drivers//:use_geckodriver": "true",
+    },
+)
+
+alias(
+    name = "msedgedriver",
+    actual = "@local_drivers//:msedgedriver",
+)
+
+config_setting(
+    name = "use_local_msedgedriver",
+    flag_values = {
+        "@local_drivers//:use_msedgedriver": "true",
+    },
+)

common/private/drivers.bzl

@@ -0,0 +1,34 @@
+
+def _symlink_if_available(repository_ctx, driver_name):
+    driver = repository_ctx.which(driver_name)
+
+    if driver:
+        repository_ctx.symlink(driver, driver_name)
+    else:
+      repository_ctx.file(driver_name, "")
+
+    return "\n".join([
+        "bool_setting(name = \"use_%s\", build_setting_default = %s)" % (driver_name, driver != None),
+        "exports_files([\"%s\"])" % driver_name,
+        "",
+    ])
+
+
+def _local_drivers_impl(repository_ctx):
+    contents = [
+      "load(\"@bazel_skylib//rules:common_settings.bzl\", \"bool_setting\")",
+      "",
+      "package(default_visibility = [\"//visibility:public\"])",
+      _symlink_if_available(repository_ctx, "chromedriver"),
+      _symlink_if_available(repository_ctx, "msedgedriver"),
+      _symlink_if_available(repository_ctx, "geckodriver"),
+    ]
+
+    repository_ctx.file("BUILD.bazel", "\n".join(contents))
+
+_local_drivers = repository_rule(
+    _local_drivers_impl,
+)
+
+def local_drivers():
+    _local_drivers(name = "local_drivers")

common/private/selenium_test.bzl

@@ -1,3 +1,12 @@
+load(
+  "//java:browsers.bzl",
+  "chrome_data",
+  "chrome_jvm_flags",
+  "edge_data",
+  "edge_jvm_flags",
+  "firefox_data",
+  "firefox_jvm_flags")
+
 DEFAULT_BROWSER = "firefox"
 
 _COMMON_TAGS = [
@@ -9,12 +18,14 @@ _COMMON_TAGS = [
 BROWSERS = {
     "chrome": {
         "deps": ["//java/client/src/org/openqa/selenium/chrome"],
-        "jvm_flags": ["-Dselenium.browser=chrome"],
+        "jvm_flags": ["-Dselenium.browser=chrome"] + chrome_jvm_flags,
+        "data": chrome_data,
         "tags": _COMMON_TAGS + ["chrome"],
     },
     "edge": {
         "deps": ["//java/client/src/org/openqa/selenium/edge"],
-        "jvm_flags": ["-Dselenium.browser=edge"],
+        "jvm_flags": ["-Dselenium.browser=edge"] + edge_jvm_flags,
+        "data": edge_data,
         "tags": _COMMON_TAGS + ["edge"],
     },
     "edgehtml": {
@@ -24,11 +35,13 @@ BROWSERS = {
                          "//common:windows": ["-Dselenium.skiptest=false"],
                          "//conditions:default": ["-Dselenium.skiptest=true"],
                      }),
+        "data": [],
         "tags": _COMMON_TAGS + ["exclusive", "edgehtml"],
     },
     "firefox": {
         "deps": ["//java/client/src/org/openqa/selenium/firefox"],
-        "jvm_flags": ["-Dselenium.browser=ff"],
+        "jvm_flags": ["-Dselenium.browser=ff"] + firefox_jvm_flags,
+        "data": firefox_data,
         "tags": _COMMON_TAGS + ["firefox"],
     },
     "ie": {
@@ -38,6 +51,7 @@ BROWSERS = {
                          "//common:windows": ["-Dselenium.skiptest=false"],
                          "//conditions:default": ["-Dselenium.skiptest=true"],
                      }),
+        "data": [],
         "tags": _COMMON_TAGS + ["exclusive", "ie"],
     },
     "safari": {
@@ -47,6 +61,7 @@ BROWSERS = {
                          "//common:macos": ["-Dselenium.skiptest=false"],
                          "//conditions:default": ["-Dselenium.skiptest=true"],
                      }),
+        "data": [],
         "tags": _COMMON_TAGS + ["exclusive", "safari"],
     },
 }
@@ -83,7 +98,7 @@ def selenium_test(name, test_class, size = "medium", browsers = None, **kwargs):
             size = size,
             jvm_flags = BROWSERS[browser]["jvm_flags"] + jvm_flags,
             tags = BROWSERS[browser]["tags"] + tags,
-            data = data,
+            data = BROWSERS[browser]["data"] + data,
             **stripped_args
         )
 
@@ -97,7 +112,7 @@ def selenium_test(name, test_class, size = "medium", browsers = None, **kwargs):
                     "-Dselenium.browser.remote.path=$(location //java/server/src/org/openqa/selenium/grid:selenium_server_deploy.jar)",
                 ],
                 tags = BROWSERS[browser]["tags"] + tags + ["remote"],
-                data = data + [
+                data = BROWSERS[browser]["data"] + data + [
                     "//java/server/src/org/openqa/selenium/grid:selenium_server_deploy.jar",
                 ],
                 **stripped_args

common/repositories.bzl

@@ -0,0 +1,6 @@
+load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
+load("//common/private:drivers.bzl", "local_drivers")
+
+def pin_browsers():
+    local_drivers()
+

java/browsers.bzl

@@ -0,0 +1,41 @@
+chrome_data = select({
+   "//common:use_local_chromedriver": ["//common:chromedriver"],
+   "//conditions:default": []
+})
+
+chrome_jvm_flags = select({
+  "//common:use_local_chromedriver": [
+      "-Dwebdriver.chrome.driver=$(location //common:chromedriver)",
+  ],
+  "//conditions:default": [
+      "-Dselenium.skiptest=true",
+  ],
+})
+
+firefox_data = select({
+   "//common:use_local_geckodriver": ["//common:geckodriver"],
+   "//conditions:default": []
+})
+
+firefox_jvm_flags = select({
+  "//common:use_local_geckodriver": [
+      "-Dwebdriver.gecko.driver=$(location //common:geckodriver)",
+  ],
+  "//conditions:default": [
+      "-Dselenium.skiptest=true",
+  ],
+})
+
+edge_data = select({
+   "//common:use_local_msedgedriver": ["//common:msedgedriver"],
+   "//conditions:default": []
+})
+
+edge_jvm_flags = select({
+  "//common:use_local_msedgedriver": [
+      "-Dwebdriver.edge.driver=$(location //common:msedgedriver)",
+  ],
+  "//conditions:default": [
+      "-Dselenium.skiptest=true",
+  ],
+})