linker: warn about orphan sections

(Previous patch set was reverted due to issue with priv_stack.
 Resubmitting after fixing the faults caused by priv_stack.noinit
 not at the end of RAM.)

This adds a linker flag and necessary changes to linker scripts
so that linker will warn about orphan sections.

Relates to #5534.

Fixes #10473, #10474, #10515.

Signed-off-by: Daniel Leung <[email protected]>

Author: dcpleung

CMakeLists.txt

@@ -287,6 +287,32 @@ zephyr_ld_options(
   ${LINKERFLAGPREFIX},--build-id=none
   )
 
+if(NOT CONFIG_NATIVE_APPLICATION)
+  # Funny thing is if this is set to =error, some architectures will
+  # skip this flag even though the compiler flag check passes
+  # (e.g. ARC and Xtensa). So warning should be the default for now.
+  #
+  # Skip this for native application as Zephyr only provides
+  # additions to the host toolchain linker script. The relocation
+  # sections (.rel*) requires us to override those provided
+  # by host toolchain. As we can't account for all possible
+  # combination of compiler and linker on all machines used
+  # for development, it is better to turn this off.
+  #
+  # CONFIG_LINKER_ORPHAN_SECTION_PLACE is to place the orphan sections
+  # without any warnings or errors, which is the default behavior.
+  # So there is no need to explicity set a linker flag.
+  if(CONFIG_LINKER_ORPHAN_SECTION_WARN)
+    zephyr_ld_options(
+      ${LINKERFLAGPREFIX},--orphan-handling=warn
+      )
+  elseif(CONFIG_LINKER_ORPHAN_SECTION_ERROR)
+    zephyr_ld_options(
+      ${LINKERFLAGPREFIX},--orphan-handling=error
+      )
+  endif()
+endif()
+
 if(CONFIG_HAVE_CUSTOM_LINKER_SCRIPT)
   set(LINKER_SCRIPT ${APPLICATION_SOURCE_DIR}/${CONFIG_CUSTOM_LINKER_SCRIPT})
   if(NOT EXISTS ${LINKER_SCRIPT})

Kconfig.zephyr

@@ -43,3 +43,26 @@ source "subsys/Kconfig"
 source "ext/Kconfig"
 
 source "tests/Kconfig"
+
+choice
+	prompt "Linker Orphan Section Handling"
+	default LINKER_ORPHAN_SECTION_WARN
+
+config LINKER_ORPHAN_SECTION_PLACE
+	bool "Place"
+	help
+	  Linker puts orphan sections in place without warnings
+	  or errors.
+
+config LINKER_ORPHAN_SECTION_WARN
+	bool "Warn"
+	help
+	  Linker places the orphan sections in ouput and issues
+	  warning about those sections.
+
+config LINKER_ORPHAN_SECTION_ERROR
+	bool "Error"
+	help
+	  Linker exits with error when an orphan section is found.
+
+endchoice

include/arch/arc/v2/linker.ld

@@ -73,6 +73,9 @@ MEMORY {
 }
 
 SECTIONS {
+
+#include <linker/rel-sections.ld>
+
 	GROUP_START(ROMABLE_REGION)
 
 	SECTION_PROLOGUE(_TEXT_SECTION_NAME,,ALIGN(1024)) {
@@ -283,4 +286,7 @@ SECTIONS {
 #ifdef CONFIG_GEN_ISR_TABLES
 #include <linker/intlist.ld>
 #endif
+
+#include <linker/debug-sections.ld>
+
 	}

include/arch/arm/cortex_m/scripts/linker.ld

@@ -87,6 +87,23 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 
 SECTIONS
     {
+
+#include <linker/rel-sections.ld>
+
+    /*
+     * .plt and .iplt are here according to 'arm-zephyr-elf-ld --verbose',
+     * before text section.
+     */
+    SECTION_PROLOGUE(.plt,,)
+	{
+	*(.plt)
+	}
+
+    SECTION_PROLOGUE(.iplt,,)
+	{
+	*(.iplt)
+	}
+
     GROUP_START(ROMABLE_REGION)
 
 	_image_rom_start = ROM_ADDR;
@@ -133,6 +150,12 @@ SECTIONS
 	*(".text.*")
 	*(.gnu.linkonce.t.*)
 
+	/*
+	 * These are here according to 'arm-zephyr-elf-ld --verbose',
+	 * after .gnu.linkonce.t.*
+	 */
+	*(.glue_7t) *(.glue_7) *(.vfp11_veneer) *(.v4_bx)
+
 #include <linker/priv_stacks-text.ld>
 #include <linker/kobject-text.ld>
 
@@ -219,6 +242,18 @@ SECTIONS
     } > FLASH_CCFG
 #endif
 
+    /*
+     * These are here according to 'arm-zephyr-elf-ld --verbose',
+     * before data section.
+     */
+    SECTION_PROLOGUE(.got,,)
+	{
+	*(.got.plt)
+	*(.igot.plt)
+	*(.got)
+	*(.igot)
+	}
+
     GROUP_START(RAMABLE_REGION)
 
 
@@ -429,4 +464,12 @@ SECTIONS
 #include <linker/intlist.ld>
 #endif
 
+#include <linker/debug-sections.ld>
+
+    SECTION_PROLOGUE(.ARM.attributes, 0,)
+	{
+	KEEP(*(.ARM.attributes))
+	KEEP(*(.gnu.attributes))
+	}
+
     }

include/arch/nios2/linker.ld

@@ -82,6 +82,23 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 
 SECTIONS
     {
+
+#include <linker/rel-sections.ld>
+
+    /*
+     * .plt and .iplt are here according to
+     * 'nios2-zephyr-elf-ld --verbose', before text section.
+     */
+    SECTION_PROLOGUE(.plt,,)
+        {
+        *(.plt)
+        }
+
+    SECTION_PROLOGUE(.iplt,,)
+        {
+        *(.iplt)
+        }
+
     GROUP_START(ROMABLE_REGION)
     _image_rom_start = _ROM_ADDR;
 
@@ -261,5 +278,7 @@ SECTIONS
 #include <linker/intlist.ld>
 #endif
 
+#include <linker/debug-sections.ld>
+
     }
 

include/arch/riscv32/common/linker.ld

@@ -46,6 +46,22 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 SECTIONS
     {
 
+#include <linker/rel-sections.ld>
+
+    /*
+     * The .plt and .iplt are here according to
+     * 'riscv32-zephyr-elf-ld --verbose', before text section.
+     */
+    SECTION_PROLOGUE(.plt,,)
+	{
+		*(.plt)
+	}
+
+    SECTION_PROLOGUE(.iplt,,)
+	{
+		*(.iplt)
+	}
+
     GROUP_START(ROM)
     _image_rom_start = .;
 
@@ -175,4 +191,7 @@ SECTIONS
 #endif
 
      GROUP_END(RAMABLE_REGION)
+
+#include <linker/debug-sections.ld>
+
 }

include/arch/riscv32/pulpino/linker.ld

@@ -41,6 +41,23 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 
 SECTIONS
     {
+
+#include <linker/rel-sections.ld>
+
+    /*
+     * .plt and .iplt are here according to
+     * 'riscv32-zephyr-elf-ld --verbose', before text section.
+     */
+    SECTION_PROLOGUE(.plt,,)
+	{
+		*(.plt)
+	}
+
+    SECTION_PROLOGUE(.iplt,,)
+	{
+		*(.iplt)
+	}
+
     GROUP_START(INSTRRAM)
 
     SECTION_PROLOGUE(_VECTOR_SECTION_NAME,,)
@@ -71,6 +88,7 @@ SECTIONS
 		*(.text)
 		*(".text.*")
 		*(.gnu.linkonce.t.*)
+		*(.eh_frame)
 	} GROUP_LINK_IN(INSTRRAM)
 
     _image_text_end = .;
@@ -160,4 +178,7 @@ SECTIONS
 #endif
 
      GROUP_END(RAMABLE_REGION)
+
+#include <linker/debug-sections.ld>
+
 }

include/arch/x86/linker.ld

@@ -66,6 +66,9 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 /* SECTIONS definitions */
 SECTIONS
 	{
+
+#include <linker/rel-sections.ld>
+
 	GROUP_START(ROMABLE_REGION)
 #ifdef CONFIG_REALMODE
 	/* 16-bit sections */
@@ -378,6 +381,8 @@ SECTIONS
 #include <custom-sections.ld>
 #endif
 
+#include <linker/debug-sections.ld>
+
 	}
 
 #ifdef CONFIG_XIP

include/linker/debug-sections.ld

@@ -0,0 +1,40 @@
+	/* following sections are obtained via 'ld --verbose' */
+
+	/* Stabs debugging sections. */
+	SECTION_PROLOGUE(.stab, 0,)            { *(.stab) }
+	SECTION_PROLOGUE(.stabstr, 0,)         { *(.stabstr) }
+	SECTION_PROLOGUE(.stab.excl, 0,)       { *(.stab.excl) }
+	SECTION_PROLOGUE(.stab.exclstr, 0,)    { *(.stab.exclstr) }
+	SECTION_PROLOGUE(.stab.index, 0,)      { *(.stab.index) }
+	SECTION_PROLOGUE(.stab.indexstr, 0,)   { *(.stab.indexstr) }
+	SECTION_PROLOGUE(.comment, 0,)         { *(.comment) }
+	/* DWARF debug sections.
+	   Symbols in the DWARF debugging sections are relative to the beginning
+	   of the section so we begin them at 0. */
+	/* DWARF 1 */
+	SECTION_PROLOGUE(.debug, 0,)           { *(.debug) }
+	SECTION_PROLOGUE(.line, 0,)            { *(.line) }
+	/* GNU DWARF 1 extensions */
+	SECTION_PROLOGUE(.debug_srcinfo, 0,)   { *(.debug_srcinfo) }
+	SECTION_PROLOGUE(.debug_sfnames, 0,)   { *(.debug_sfnames) }
+	/* DWARF 1.1 and DWARF 2 */
+	SECTION_PROLOGUE(.debug_aranges, 0,)   { *(.debug_aranges) }
+	SECTION_PROLOGUE(.debug_pubnames, 0,)  { *(.debug_pubnames) }
+	/* DWARF 2 */
+	SECTION_PROLOGUE(.debug_info, 0,)      { *(.debug_info .gnu.linkonce.wi.*) }
+	SECTION_PROLOGUE(.debug_abbrev, 0,)    { *(.debug_abbrev) }
+	SECTION_PROLOGUE(.debug_line, 0,)      { *(.debug_line .debug_line.* .debug_line_end ) }
+	SECTION_PROLOGUE(.debug_frame, 0,)     { *(.debug_frame) }
+	SECTION_PROLOGUE(.debug_str, 0,)       { *(.debug_str) }
+	SECTION_PROLOGUE(.debug_loc, 0,)       { *(.debug_loc) }
+	SECTION_PROLOGUE(.debug_macinfo, 0,)   { *(.debug_macinfo) }
+	/* SGI/MIPS DWARF 2 extensions */
+	SECTION_PROLOGUE(.debug_weaknames, 0,) { *(.debug_weaknames) }
+	SECTION_PROLOGUE(.debug_funcnames, 0,) { *(.debug_funcnames) }
+	SECTION_PROLOGUE(.debug_typenames, 0,) { *(.debug_typenames) }
+	SECTION_PROLOGUE(.debug_varnames, 0,)  { *(.debug_varnames) }
+	/* DWARF 3 */
+	SECTION_PROLOGUE(.debug_pubtypes, 0,)  { *(.debug_pubtypes) }
+	SECTION_PROLOGUE(.debug_ranges, 0,)    { *(.debug_ranges) }
+	/* DWARF Extension. */
+	SECTION_PROLOGUE(.debug_macro, 0,)     { *(.debug_macro) }

include/linker/rel-sections.ld

@@ -0,0 +1,33 @@
+	/*
+	 * .rel.* are for relocation.
+	 * These are being produced by compiler/linker.
+	 * Specify these here so they are not considered orphan sections.
+	 */
+
+	SECTION_PROLOGUE(.rel.plt,,)
+	{
+	*(.rel.plt)
+
+	PROVIDE_HIDDEN (__rel_iplt_start = .);
+	*(.rel.iplt)
+	PROVIDE_HIDDEN (__rel_iplt_end = .);
+	}
+
+	SECTION_PROLOGUE(.rela.plt,,)
+	{
+	*(.rela.plt)
+
+	PROVIDE_HIDDEN (__rela_iplt_start = .);
+	*(.rela.iplt)
+	PROVIDE_HIDDEN (__rela_iplt_end = .);
+	}
+
+	SECTION_PROLOGUE(.rel.dyn,,)
+	{
+	*(.rel.*)
+	}
+
+	SECTION_PROLOGUE(.rela.dyn,,)
+	{
+	*(.rela.*)
+	}

soc/xtensa/D_108mini/linker.ld

@@ -178,6 +178,8 @@ PROVIDE(_memmap_cacheattr_reset = _memmap_cacheattr_wb_trapnull);
 SECTIONS
 {
 
+#include <linker/rel-sections.ld>
+
   .dram1.rodata : ALIGN(4)
   {
     _dram1_rodata_start = ABSOLUTE(.);
@@ -563,6 +565,7 @@ SECTIONS
   } >sram0_seg :sram0_bss_phdr
   __stack = 0x64000000;
   _heap_sentry = 0x64000000;
+  .comment  0 :  { *(.comment) }
   .debug  0 :  { *(.debug) }
   .line  0 :  { *(.line) }
   .debug_srcinfo  0 :  { *(.debug_srcinfo) }
@@ -580,6 +583,8 @@ SECTIONS
   .debug_funcnames  0 :  { *(.debug_funcnames) }
   .debug_typenames  0 :  { *(.debug_typenames) }
   .debug_varnames  0 :  { *(.debug_varnames) }
+  .debug_ranges  0 :  { *(.debug_ranges) }
+  .xtensa.info  0 :  { *(.xtensa.info) }
   .xt.insn 0 :
   {
     KEEP (*(.xt.insn))

soc/xtensa/D_212GP/linker.ld

@@ -178,6 +178,8 @@ PROVIDE(_memmap_cacheattr_reset = _memmap_cacheattr_wb_trapnull);
 SECTIONS
 {
 
+#include <linker/rel-sections.ld>
+
   .dport0.rodata : ALIGN(4)
   {
     _dport0_rodata_start = ABSOLUTE(.);
@@ -569,6 +571,7 @@ SECTIONS
   } >sram19_seg :sram19_bss_phdr
   __stack = 0x64000000;
   _heap_sentry = 0x64000000;
+  .comment  0 :  { *(.comment) }
   .debug  0 :  { *(.debug) }
   .line  0 :  { *(.line) }
   .debug_srcinfo  0 :  { *(.debug_srcinfo) }
@@ -586,6 +589,8 @@ SECTIONS
   .debug_funcnames  0 :  { *(.debug_funcnames) }
   .debug_typenames  0 :  { *(.debug_typenames) }
   .debug_varnames  0 :  { *(.debug_varnames) }
+  .debug_ranges  0 :  { *(.debug_ranges) }
+  .xtensa.info  0 :  { *(.xtensa.info) }
   .xt.insn 0 :
   {
     KEEP (*(.xt.insn))