linker: warn about orphan sections

This adds a linker flag and necessary changes to linker scripts
so that linker will warn about orphan sections.

Relates to #5534.

Signed-off-by: Daniel Leung <[email protected]>

Author: dcpleung

CMakeLists.txt

@@ -287,6 +287,13 @@ zephyr_ld_options(
   ${LINKERFLAGPREFIX},--build-id=none
   )
 
+# Funny thing is if this is set to =error, some architectures will
+# skip this flag even though the compiler flag check passes
+# (e.g. ARC and Xtensa). So keep it at =warn, for now.
+zephyr_ld_options(
+  ${LINKERFLAGPREFIX},--orphan-handling=warn
+  )
+
 if(CONFIG_HAVE_CUSTOM_LINKER_SCRIPT)
   set(LINKER_SCRIPT ${APPLICATION_SOURCE_DIR}/${CONFIG_CUSTOM_LINKER_SCRIPT})
   if(NOT EXISTS ${LINKER_SCRIPT})

include/arch/arc/v2/linker.ld

@@ -73,6 +73,9 @@ MEMORY {
 }
 
 SECTIONS {
+
+#include <linker/rel-sections.ld>
+
 	GROUP_START(ROMABLE_REGION)
 
 	SECTION_PROLOGUE(_TEXT_SECTION_NAME,,ALIGN(1024)) {
@@ -283,4 +286,7 @@ SECTIONS {
 #ifdef CONFIG_GEN_ISR_TABLES
 #include <linker/intlist.ld>
 #endif
+
+#include <linker/debug-sections.ld>
+
 	}

include/arch/arm/cortex_m/scripts/linker.ld

@@ -87,6 +87,23 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 
 SECTIONS
     {
+
+#include <linker/rel-sections.ld>
+
+    /*
+     * .plt and .iplt are here according to 'arm-zephyr-elf-ld --verbose',
+     * before text section.
+     */
+    SECTION_PROLOGUE(.plt,,)
+	{
+	*(.plt)
+	}
+
+    SECTION_PROLOGUE(.iplt,,)
+	{
+	*(.iplt)
+	}
+
     GROUP_START(ROMABLE_REGION)
 
 	_image_rom_start = ROM_ADDR;
@@ -133,6 +150,12 @@ SECTIONS
 	*(".text.*")
 	*(.gnu.linkonce.t.*)
 
+	/*
+	 * These are here according to 'arm-zephyr-elf-ld --verbose',
+	 * after .gnu.linkonce.t.*
+	 */
+	*(.glue_7t) *(.glue_7) *(.vfp11_veneer) *(.v4_bx)
+
 #include <linker/priv_stacks-text.ld>
 #include <linker/kobject-text.ld>
 
@@ -219,6 +242,18 @@ SECTIONS
     } > FLASH_CCFG
 #endif
 
+    /*
+     * These are here according to 'arm-zephyr-elf-ld --verbose',
+     * before data section.
+     */
+    SECTION_PROLOGUE(.got,,)
+	{
+	*(.got.plt)
+	*(.igot.plt)
+	*(.got)
+	*(.igot)
+	}
+
     GROUP_START(RAMABLE_REGION)
 
 
@@ -319,6 +354,8 @@ SECTIONS
 	KERNEL_INPUT_SECTION(COMMON)
 	*(".kernel_bss.*")
 
+#include <linker/priv_stacks-noinit.ld>
+
         /*
          * As memory is cleared in words only, it is simpler to ensure the BSS
          * section ends on a 4 byte boundary. This wastes a maximum of 3 bytes.
@@ -427,4 +464,12 @@ SECTIONS
 #include <linker/intlist.ld>
 #endif
 
+#include <linker/debug-sections.ld>
+
+    SECTION_PROLOGUE(.ARM.attributes, 0,)
+	{
+	KEEP(*(.ARM.attributes))
+	KEEP(*(.gnu.attributes))
+	}
+
     }

include/arch/nios2/linker.ld

@@ -82,6 +82,23 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 
 SECTIONS
     {
+
+#include <linker/rel-sections.ld>
+
+    /*
+     * .plt and .iplt are here according to
+     * 'nios2-zephyr-elf-ld --verbose', before text section.
+     */
+    SECTION_PROLOGUE(.plt,,)
+        {
+        *(.plt)
+        }
+
+    SECTION_PROLOGUE(.iplt,,)
+        {
+        *(.iplt)
+        }
+
     GROUP_START(ROMABLE_REGION)
     _image_rom_start = _ROM_ADDR;
 
@@ -261,5 +278,7 @@ SECTIONS
 #include <linker/intlist.ld>
 #endif
 
+#include <linker/debug-sections.ld>
+
     }
 

include/arch/posix/linker.ld

@@ -21,16 +21,43 @@
 #include <linker/linker-defs.h>
 #include <linker/linker-tool.h>
 
+SECTIONS
+ {
+	SECTION_PROLOGUE(.note.ABI-tag,,)
+	{
+	*(.note.ABI-tag)
+	}
+
+ } INSERT AFTER .interp;
 
 SECTIONS
  {
 
+#include <linker/rel-sections.ld>
+
 #include <linker/common-rom.ld>
 
 #include <linker/common-ram.ld>
 
+	SECTION_PROLOGUE(_NOINIT_SECTION_NAME, (NOLOAD OPTIONAL),)
+	{
+	/*
+	 * This section is used for non-initialized objects that
+	 * will not be cleared during the boot process.
+	 */
+	KERNEL_INPUT_SECTION(.noinit)
+	KERNEL_INPUT_SECTION(".noinit.*")
+	*(".kernel_noinit.*")
+	}
+
 #include <arch/posix/native_tasks.ld>
 
+	/* Related to transactional memory */
+	SECTION_PROLOGUE(.tm_clone_table,,)
+	{
+	*(.tm_clone_table)
+	}
+
  __data_ram_end = .;
 
  } INSERT AFTER .data;

include/arch/riscv32/common/linker.ld

@@ -46,6 +46,22 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 SECTIONS
     {
 
+#include <linker/rel-sections.ld>
+
+    /*
+     * The .plt and .iplt are here according to
+     * 'riscv32-zephyr-elf-ld --verbose', before text section.
+     */
+    SECTION_PROLOGUE(.plt,,)
+	{
+		*(.plt)
+	}
+
+    SECTION_PROLOGUE(.iplt,,)
+	{
+		*(.iplt)
+	}
+
     GROUP_START(ROM)
     _image_rom_start = .;
 
@@ -175,4 +191,7 @@ SECTIONS
 #endif
 
      GROUP_END(RAMABLE_REGION)
+
+#include <linker/debug-sections.ld>
+
 }

include/arch/riscv32/pulpino/linker.ld

@@ -41,6 +41,23 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 
 SECTIONS
     {
+
+#include <linker/rel-sections.ld>
+
+    /*
+     * .plt and .iplt are here according to
+     * 'riscv32-zephyr-elf-ld --verbose', before text section.
+     */
+    SECTION_PROLOGUE(.plt,,)
+	{
+		*(.plt)
+	}
+
+    SECTION_PROLOGUE(.iplt,,)
+	{
+		*(.iplt)
+	}
+
     GROUP_START(INSTRRAM)
 
     SECTION_PROLOGUE(_VECTOR_SECTION_NAME,,)
@@ -71,6 +88,7 @@ SECTIONS
 		*(.text)
 		*(".text.*")
 		*(.gnu.linkonce.t.*)
+		*(.eh_frame)
 	} GROUP_LINK_IN(INSTRRAM)
 
     _image_text_end = .;
@@ -160,4 +178,7 @@ SECTIONS
 #endif
 
      GROUP_END(RAMABLE_REGION)
+
+#include <linker/debug-sections.ld>
+
 }

include/arch/x86/linker.ld

@@ -66,6 +66,9 @@ ENTRY(CONFIG_KERNEL_ENTRY)
 /* SECTIONS definitions */
 SECTIONS
 	{
+
+#include <linker/rel-sections.ld>
+
 	GROUP_START(ROMABLE_REGION)
 #ifdef CONFIG_REALMODE
 	/* 16-bit sections */
@@ -378,6 +381,8 @@ SECTIONS
 #include <custom-sections.ld>
 #endif
 
+#include <linker/debug-sections.ld>
+
 	}
 
 #ifdef CONFIG_XIP

include/linker/debug-sections.ld

@@ -0,0 +1,40 @@
+	/* following sections are obtained via 'ld --verbose' */
+
+	/* Stabs debugging sections. */
+	SECTION_PROLOGUE(.stab, 0,)            { *(.stab) }
+	SECTION_PROLOGUE(.stabstr, 0,)         { *(.stabstr) }
+	SECTION_PROLOGUE(.stab.excl, 0,)       { *(.stab.excl) }
+	SECTION_PROLOGUE(.stab.exclstr, 0,)    { *(.stab.exclstr) }
+	SECTION_PROLOGUE(.stab.index, 0,)      { *(.stab.index) }
+	SECTION_PROLOGUE(.stab.indexstr, 0,)   { *(.stab.indexstr) }
+	SECTION_PROLOGUE(.comment, 0,)         { *(.comment) }
+	/* DWARF debug sections.
+	   Symbols in the DWARF debugging sections are relative to the beginning
+	   of the section so we begin them at 0. */
+	/* DWARF 1 */
+	SECTION_PROLOGUE(.debug, 0,)           { *(.debug) }
+	SECTION_PROLOGUE(.line, 0,)            { *(.line) }
+	/* GNU DWARF 1 extensions */
+	SECTION_PROLOGUE(.debug_srcinfo, 0,)   { *(.debug_srcinfo) }
+	SECTION_PROLOGUE(.debug_sfnames, 0,)   { *(.debug_sfnames) }
+	/* DWARF 1.1 and DWARF 2 */
+	SECTION_PROLOGUE(.debug_aranges, 0,)   { *(.debug_aranges) }
+	SECTION_PROLOGUE(.debug_pubnames, 0,)  { *(.debug_pubnames) }
+	/* DWARF 2 */
+	SECTION_PROLOGUE(.debug_info, 0,)      { *(.debug_info .gnu.linkonce.wi.*) }
+	SECTION_PROLOGUE(.debug_abbrev, 0,)    { *(.debug_abbrev) }
+	SECTION_PROLOGUE(.debug_line, 0,)      { *(.debug_line .debug_line.* .debug_line_end ) }
+	SECTION_PROLOGUE(.debug_frame, 0,)     { *(.debug_frame) }
+	SECTION_PROLOGUE(.debug_str, 0,)       { *(.debug_str) }
+	SECTION_PROLOGUE(.debug_loc, 0,)       { *(.debug_loc) }
+	SECTION_PROLOGUE(.debug_macinfo, 0,)   { *(.debug_macinfo) }
+	/* SGI/MIPS DWARF 2 extensions */
+	SECTION_PROLOGUE(.debug_weaknames, 0,) { *(.debug_weaknames) }
+	SECTION_PROLOGUE(.debug_funcnames, 0,) { *(.debug_funcnames) }
+	SECTION_PROLOGUE(.debug_typenames, 0,) { *(.debug_typenames) }
+	SECTION_PROLOGUE(.debug_varnames, 0,)  { *(.debug_varnames) }
+	/* DWARF 3 */
+	SECTION_PROLOGUE(.debug_pubtypes, 0,)  { *(.debug_pubtypes) }
+	SECTION_PROLOGUE(.debug_ranges, 0,)    { *(.debug_ranges) }
+	/* DWARF Extension. */
+	SECTION_PROLOGUE(.debug_macro, 0,)     { *(.debug_macro) }

include/linker/priv_stacks-noinit.ld

@@ -0,0 +1,7 @@
+/*
+ * Copyright (c) 2017 Linaro Limited.
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+	*(".priv_stacks.noinit")